laybtn_ease()

layerbuttonサブルーチン内用イージング値の取得

val = laybtn_ease(p1,p2,p3,p4)

(プラグイン / モジュール : mod_layerbutton)

解説

p1 と p2 で指定された最小値・最大値の範囲内で、任意の計算式に基づき補間されたイージング関数の結果値を取得します。
この結果値は、layerbutton 命令の p5 〜 p10 に設定された各ボタン状態の表示にかけるフレーム数(時間範囲)に対し、layerbtn_cnt の値を経過時間として算出されます。

p3 の遅延フレーム数は、同一グループ内で複数のボタンを作成する場合に、2つ目以降の SHOW_IN 表示等を意図的に遅らせ、段階的に表示させる用途に使用します。

イージングの計算式タイプは、LAYBTN_SHOW_IN などのボタン状態ごとにデフォルトのタイプが決まっています。
これを、引数 p4 で計算式タイプを強制することができます。
イージングの計算式タイプについて詳しくは、setease命令のコマンドヘルプを参照してください。

※ laybtn_settings命令で設定を「FOCUS_IN の表示が完了する前にフォーカスが外れたとき FOCUS_OUT を即座に開始させる」にしている場合、LAYBTN_FOCUS_OUT のデフォルトタイプは ease_quartic_in になります。

サンプル

#include "mod_layerbutton.hsp"

// ボタン作成
pos 10,100
repeat 4
	tien = 10*cnt
	pos ,ginfo_cy+10
	layerbutton 180,60, tien, 0, 30+tien,20,0, 15+tien/2,10,0 {
		if lparam == objlayer_cmddraw {
			color 0,0,0 : font msgothic, 18, 1
			ti = objlayer_option
			// ボタン状態で分岐 (+イージングで表示位置,色を変える)
			switch layerbtn_stat
			case LAYBTN_SHOW_IN
				color 0,0,255 : boxf objlayer_axis_x-laybtn_ease(200, 0, ti), objlayer_axis_y, objlayer_axis_x2-laybtn_ease(200, 0, ti), objlayer_axis_y2
				color 250,250,250 : laybtn_mes "遅延="+ti,0, 1,1, -laybtn_ease(200, 0, ti)
				swbreak
			case LAYBTN_FOCUS_IN
				color laybtn_ease(0,128),0,255 : boxf objlayer_axis_x, objlayer_axis_y, objlayer_axis_x2, objlayer_axis_y2
				color 250,250,250 : laybtn_mes "遅延="+ti,0, 1,1
				swbreak
			case LAYBTN_FOCUS_OUT
				color laybtn_ease(128,0),0,255 : boxf objlayer_axis_x, objlayer_axis_y, objlayer_axis_x2, objlayer_axis_y2
				color 250,250,250 : laybtn_mes "遅延="+ti,0, 1,1
				swbreak
			case LAYBTN_PRESS_IN
				color 128,128,255 : boxf objlayer_axis_x, objlayer_axis_y, objlayer_axis_x2, objlayer_axis_y2
				color 250,250,250 : laybtn_mes "遅延="+ti,0, 1,1
				swbreak
			case LAYBTN_SHOW_OUT
			case LAYBTN_SHOW_OUT_SELECTED
				if layerbtn_stat & LAYBTN_SELECTED { color 128,128,255 } else { color 0,0,255 }
				boxf objlayer_axis_x-laybtn_ease(0, 200, ti/2), objlayer_axis_y, objlayer_axis_x2-laybtn_ease(0, 200, ti/2), objlayer_axis_y2
				color 250,250,250 : laybtn_mes "遅延="+ti,0, 1,1, -laybtn_ease(0, 200, ti/2)
				swbreak
			swend
		}
		return
	}
loop
// 表示ループ
repeat
	redraw 0 : color 255,255,255 : boxf : color : pos 0,0 : font msgothic,17
	redraw 1
	await 1000/60
loop

関連項目

サンプル逆引き (3)

情報