HSPTV!掲示板

例えば
http://www.isotope6301.shop/a.png
の画像をダウンロードしたいとき、どのようにコードを書けばいいのでしょうか

http://hsp.tv/play/pforum.php?mode=pastwch&num=47840
を見てみたのですがエラーが出てうまくできませんでした。

inoviaさんのソースをちょっといじっただけですが自分の環境では表示されました。

// HSP3.31β1以降が必要です
// http://www.onionsoft.net/wp/archives/730

// sample\hspinet\test6.hsp
#include "hspinet.as"

	;
	;	ファイルの取得(メモリ上に取得)
	;

	netinit
	neturl "http://www.isotope6301.shop/"
	netrequest_get "a.png"
	
	mes "DOWNLOAD 開始"

*main
	;	結果待ちのためのループ
	netexec res
	if res > 0 : goto *comp
	if res < 0 : goto *bad
	await 50
	goto *main

*bad
	;	エラー
	neterror estr
	mes "ERROR "+estr
stop

*comp
	;	完了
	mes "DOWNLOAD 完了"
	// 変数にダウンロードしたデータを保存
	netgetv buf
	// メモリストリーム設定
	memfile buf, 0, stat
	// picloadで読み込み
	picload "MEM:a.png"
stop

返信ありがとうございます！

HSPを入れなおしたら画像を表示できました。
bmpsaveで保存をすることはできたのですが、
できれば透明度をそのまま保存したいのですができますかね？

hsp3 同梱のa2dモジュールのalsavefile命令を使えば
出来ると思います

過去に「透過画像の保存」のスレッドがあったので
参考になるか分かりませんが、貼っておきます

http://hsp.tv/play/pforum.php?mode=pastwch&num=88804

返信ありがとうございました！

自己解決しましたので報告させていただきます。

#include "hspinet.as"

filename = "b.png"

*start
	netinit
	neturl "http://www.isotope6301.shop/"
	netrequest_get filename
	mes "DOWNLOAD 開始"

*main
	;	結果待ちのためのループ
	netexec res
	if res > 0 : goto *comp
	if res < 0 : goto *bad
	await 60/1000
goto *main

*bad
	;	エラー
	neterror estr
	mes "ERROR "+estr
stop

*comp
	;	完了
	mes "DOWNLOAD 完了"
	// 変数にダウンロードしたデータを保存
	netgetv buf
	// メモリストリーム設定
	memfile buf, 0, stat
	// デスクトップにコピー
	bcopy "MEM:"+filename, "C:\\Users\\"+sysinfo(1)+"\\Desktop\\"+filename
	mes "成功"
stop